{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    stable.url = "github:NixOS/nixpkgs/nixos-24.11";
    nixpkgs-droid.url = "github:NixOS/nixpkgs/nixos-24.05";

    distro-grub-themes = {
      url = "github:AdisonCavani/distro-grub-themes";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    pre-commit-hooks.url = "github:cachix/pre-commit-hooks.nix";
    pre-commit-hooks.inputs.nixpkgs.follows = "nixpkgs";

    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    # simple mailserver
    snm = {
      url = "gitlab:simple-nixos-mailserver/nixos-mailserver/master";
      #      inputs.nixpkgs-23_05.follows = "nixpkgs";
    };

    nix-on-droid = {
      url = "github:t184256/nix-on-droid/release-24.05";
      inputs.nixpkgs.follows = "nixpkgs-droid";
    };

    # age for nix to store encrypted passwords conveniently
    agenix = {
      url = "github:ryantm/agenix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    disko.url = "github:nix-community/disko";
    disko.inputs.nixpkgs.follows = "nixpkgs";
  };

  outputs =
    {
      self,
      home-manager,
      nixpkgs,
      stable,
      pre-commit-hooks,
      ...
    }@inputs:
    {
      checks."x86_64-linux" =
        let
          system = "x86_64-linux";
          pkgs = import nixpkgs { inherit system; };
        in
        {
          pre-commit-check = pre-commit-hooks.lib.${system}.run {
            src = ./.;
            tools.fourmolu = pkgs.haskellPackages.fourmolu;
            tools.nixfmt = pkgs.nixfmt-rfc-style;
            hooks = {
              nixfmt-rfc-style.enable = true;
              fourmolu.enable = true;
              hpack.enable = true;
              hlint.enable = true;
              ormolu = {
                settings.defaultExtensions = [ "GHC2021" ];
              };
            };
          };
        };

      nixosConfigurations."thrall" = nixpkgs.lib.nixosSystem rec {
        system = "x86_64-linux";
        specialArgs = {
          inherit inputs;
          inherit system;
        };
        modules = [
          (
            { inputs, lib, ... }:
            {
              nixpkgs = {
                config.allowUnfree = true;
                # overlays = with inputs; [
                #   emacs.overlay
                # ];
              };
            }
          )
          ./hosts/thrall
          home-manager.nixosModules.home-manager
          {
            home-manager.useGlobalPkgs = true;
            home-manager.useUserPackages = true;
            home-manager.extraSpecialArgs = {
              inherit inputs;
            };
          }
          { home-manager.users.alex = ./hosts/thrall/alex.nix; }
        ];
      };

      nixosConfigurations."dregil" = nixpkgs.lib.nixosSystem rec {
        system = "x86_64-linux";
        specialArgs = {
          inherit inputs;
          inherit system;
          stable = import inputs.stable { system = "x86_64-linux"; };
        };
        modules = [ ./hosts/dregil ];
      };

      nixosConfigurations."igor" = nixpkgs.lib.nixosSystem {
        system = "x86_64-linux";
        specialArgs = {
          inherit inputs;
        };
        modules = [ ./hosts/igor ];
      };

      homeConfigurations."alex@dregil" = home-manager.lib.homeManagerConfiguration {

      };

      nixOnDroidConfigurations.default =
        with inputs;
        nix-on-droid.lib.nixOnDroidConfiguration {
          pkgs = import nixpkgs-droid { };
          modules = [
            ./hosts/redmi
            { nix.registry.nixpkgs.flake = nixpkgs-droid; }
            { nix.nixPath = [ "nixpkgs=${nixpkgs-droid}" ]; }
          ];
        };

      devShells."x86_64-linux".default =
        let
          system = "x86_64-linux";
          pkgs = import nixpkgs { inherit system; };
        in
        pkgs.mkShell {
          inherit (self.checks.${system}.pre-commit-check) shellHook;

          packages = with pkgs; [
            nixfmt-rfc-style
            nil
          ];
        };
    };
}