{
  config,
  lib,
  pkgs,
  stable,
  ...
}:
{
  imports = [
    ./cli.nix
    ./programs/rofi
    ./programs/xmonad
    #./programs/i3
    ./programs/jitsi-meet
    ./programs/simplex-chat
    ./programs/zathura
    ./programs/autorandr
    ./services/polybar
    ./services/dunst
    ./services/udiskie
    # ./services/picom
    ./services/screen-locker
    ./services/blueman-applet
    ./services/network-manager
    ./services/syncthing
    ./services/git-sync
    ./modules/email.nix
  ];

  home = {
    homeDirectory = "/home/alex";
    stateVersion = "21.05";

    language.base = "en_US.UTF-8";

    keyboard.layout = "us";
    keyboard.variant = "dvorak";
    keyboard.options = [
      "terminate:ctrl_alt_bksp"
      "caps:escape"
      "compose:ralt"
    ];

    packages = with pkgs; [
      # social
      discord # talk to other people
      google-chrome

      # system tools
      uhk-agent # my keyboard
      mosh # ssh via udp
      rclone
      parallel-disk-usage
      gdu

      # gaming support
      stable.bottles
      wine64Packages.stagingFull
      scummvm

      # reading
      xournalpp # pdf editor
    ];
  };

  news.display = "silent";

  my.git-sync.enable = true;

  programs = {
    alacritty.enable = true;

    browserpass = {
      enable = true;
      browsers = [ "firefox" ];
    };

    feh.enable = true;
    firefox = {
      enable = true;
      package = pkgs.firefox.override {
        cfg = {
          nativeMessagingHosts.packages = [
            pkgs.browserpass
            pkgs.tridactyl-native
          ];
          enableGnomeExtensions = true;
        };
      };
    };
    mpv.enable = true;

    zsh =
      let
        auth-socket-env = ''
          export SSH_AUTH_SOCK="$(${pkgs.gnupg}/bin/gpgconf -L agent-ssh-socket)"
        '';
      in
      {
        enable = true;
        loginExtra = auth-socket-env;
        initExtra = auth-socket-env;
      };
  };

  services.gpg-agent = {
    enable = true;
    enableSshSupport = true;
    sshKeys = [ "9027AB16B9A7C20BD29F30F55CBA054430BF014C" ];
    extraConfig = ''
      pinentry-program ${pkgs.pinentry.qt}/bin/pinentry
    '';
  };

  xsession.enable = true;
}