inputs:
with inputs;
let
  electron-overlay = final: prev: { electron = final.electron_25; };
  pkgs = import nixpkgs-unstable {
    system = "x86_64-linux";
    config.allowUnfree = true;
    overlays = [ emacs.overlay electron-overlay ];
  };
in {
  "alex@dregil" = home-manager-unstable.lib.homeManagerConfiguration {
    inherit pkgs;
    modules = [
      ../../home/cli.nix
      {
        home = {
          language.base = "en_US.UTF-8";

          keyboard.layout = "us";
          keyboard.variant = "dvorak";
          keyboard.options =
            [ "terminate:ctrl_alt_bksp" "caps:escape" "compose:ralt" ];

          packages = with pkgs; [
            # social
            (jitsi-meet-electron.overrideAttrs (prev: rec {
              version = "2023.10.0";
              src = fetchurl {
                url =
                  "https://github.com/jitsi/jitsi-meet-electron/releases/download/v${version}/jitsi-meet-x86_64.AppImage";
                sha256 = "sha256-zhOx/gdsiQMuOCCE5sn+JNu0WJrH36XfvqqNvE24St8=";
                name = "jitsi-meet-electron-${version}.AppImage";
              };
            })) # jitsi as a stand-alone app
            discord # talk to other people

            # system tools
            uhk-agent # my keyboard
            mosh # ssh via udp

            # gaming support
            lutris
            winePackages.stagingFull

            # reading
            calibre
          ];
        };

        news.display = "silent";

        programs = {
          home-manager.enable = true;

          alacritty.enable = true;
          # autorandr.enable = true;

          browserpass = {
            enable = true;
            browsers = [ "firefox" ];
          };

          feh.enable = true;
          firefox = {
            enable = true;
            package = pkgs.firefox.override {
              cfg = {
                enableGnomeExtensions = true;
                enableTridactylNative = true;
                enableBrowserpass = true;
              };
            };
          };
          mpv.enable = true;
          rofi.enable = true;
          rofi.pass.enable = true;
          zathura.enable = true;

          zsh = let
            auth-socket-env = ''
              export SSH_AUTH_SOCK="$(${pkgs.gnupg}/bin/gpgconf -L agent-ssh-socket)"
            '';
          in {
            enable = true;
            loginExtra = auth-socket-env;
            initExtra = auth-socket-env;
          };
        };

        services.gpg-agent = {
          enable = true;
          enableSshSupport = true;
          sshKeys = [ "9027AB16B9A7C20BD29F30F55CBA054430BF014C" ];
        };

        # services.autorandr = { enable = true; };

        xsession.enable = true;
      }
    ];
  };
}